ACIL FM

Nama	Ukuran	Aksi
alloc	-	Open
debugfs	-	Open
atomic_as_refcounter.cocci	2.22 MB	View DL Edit
check_bq27xxx_data.cocci	3.46 MB	View DL Edit
device_attr_show.cocci	1.08 MB	View DL Edit
d_find_alias.cocci	1.28 MB	View DL Edit
err_cast.cocci	1.09 MB	View DL Edit
kfree_mismatch.cocci	5.56 MB	View DL Edit
kfree_sensitive.cocci	1.91 MB	View DL Edit
kstrdup.cocci	2.42 MB	View DL Edit
kvmalloc.cocci	6.13 MB	View DL Edit
memdup.cocci	1.33 MB	View DL Edit
memdup_user.cocci	2.58 MB	View DL Edit
platform_get_irq.cocci	1.22 MB	View DL Edit
platform_no_drv_owner.cocci	3.81 MB	View DL Edit
pm_runtime.cocci	2.37 MB	View DL Edit
resource_size.cocci	2.08 MB	View DL Edit
simple_open.cocci	1.21 MB	View DL Edit
stream_open.cocci	7.7 MB	View DL Edit
vma_pages.cocci	1.48 MB	View DL Edit

Edit file: /usr/src/kernels/5.14.0-611.34.1.el9_7.x86_64/scripts/coccinelle/api/resource_size.cocci

// SPDX-License-Identifier: GPL-2.0-only
///
/// Use resource_size function on resource object
/// instead of explicit computation.
///
//  Confidence: High
//  Copyright: (C) 2009, 2010 Nicolas Palix, DIKU.
//  Copyright: (C) 2009, 2010 Julia Lawall, DIKU.
//  Copyright: (C) 2009, 2010 Gilles Muller, INRIA/LiP6.
//  URL: http://coccinelle.lip6.fr/
//  Options:
//
//  Keywords: resource_size
//  Version min: 2.6.27 resource_size
//

virtual context
virtual patch
virtual org
virtual report

//----------------------------------------------------------
//  For context mode
//----------------------------------------------------------

@r_context depends on context && !patch && !org@
struct resource *res;
@@

* (res->end - res->start) + 1

//----------------------------------------------------------
//  For patch mode
//----------------------------------------------------------

@r_patch depends on !context && patch && !org@
struct resource *res;
@@

- (res->end - res->start) + 1
+ resource_size(res)

//----------------------------------------------------------
//  For org mode
//----------------------------------------------------------

@r_org depends on !context && !patch && (org || report)@
struct resource *res;
position p;
@@

(res->end@p - res->start) + 1

@rbad_org depends on !context && !patch && (org || report)@
struct resource *res;
position p != r_org.p;
@@

res->end@p - res->start

@script:python depends on org@
p << r_org.p;
x << r_org.res;
@@

msg="ERROR with %s" % (x)
msg_safe=msg.replace("[","@(").replace("]",")")
coccilib.org.print_todo(p[0], msg_safe)

@script:python depends on report@
p << r_org.p;
x << r_org.res;
@@

msg="ERROR: Missing resource_size with %s" % (x)
coccilib.report.print_report(p[0], msg)

@script:python depends on org@
p << rbad_org.p;
x << rbad_org.res;
@@

msg="WARNING with %s" % (x)
msg_safe=msg.replace("[","@(").replace("]",")")
coccilib.org.print_todo(p[0], msg_safe)

@script:python depends on report@
p << rbad_org.p;
x << rbad_org.res;
@@

msg="WARNING: Suspicious code. resource_size is maybe missing with %s" % (x)
coccilib.report.print_report(p[0], msg)

Batal